Crashing + Addons = Reset Configuration

[Rossbot]

I've been having issues with my addons resetting when I crash sometimes. Is there a way to hold these settings, maybe make a duplicate, so I don't have to set up my addons just the way I like them? If there is a way to do this, I would greatly appreciate it.

[masterdesh]

I don't know but I as well have had the issues where just logging out can cause my add ons to reset I would be interested to see what people would have to say about this

[Peryl]

I've been having issues with my addons resetting when I crash sometimes. Is there a way to hold these settings, maybe make a duplicate, so I don't have to set up my addons just the way I like them? If there is a way to do this, I would greatly appreciate it.

This can happen after a crash because the add-on variables aren't being saved. To manually make a backup of your settings, Go into your Document and Settings (or wherever your documents are normally stored) and find the hidden folder called Runes of Magic (you may need to enter the name manually in the address bar since it is a hidden folder). In this folder you will find a file called SaveVariables.lua. Make a copy of this file. Now for each of your characters, you will also find a folder here with the character's name. Enter each folder and make a backup of the SaveVariables.lua file you find in these as well.

To restore, delete the old file and copy/rename the backup version.

You could make a batch file to help automate the process. Something like:
(edit: Ignore these batch files, use the ones posted a little later instead. These are just examples to get the mind working )

@echo off
rem **** Backup Main Settings ****
cd "C:\Documents and Settings\Runes of Magic\"
if NOT EXIST Backup md Backup
copy /y SaveVariables.lua .\Backup

rem **** Backup Character ****
rem the following assumes a character named Peryl
cd Backup
if NOT EXIST Peryl md Peryl
cd ..
copy /y .\Peryl\SaveVariables.lua .\Backup\Peryl

To restore you could do:

@echo off
rem **** Restore Main Settings ****
cd "C:\Documents and Settings\Runes of Magic\"
if NOT EXIST Backup goto abort
copy /y .\Backup\SaveVariables.lua .

rem **** Restore Character ****
if NOT EXIST Peryl goto abort
copy /y .\Backup\Peryl\SaveVariables.lua .\Peryl

abort:

[Stagg3r]

I'll echo what Peryl (Edit: sorry about that...was typing on the Kindle... auto correct is nuts) said about the folder to save. I just want to add that what can also happen, especially when you crash, is that the savevariables file gets corrupted and the game then cannot read it even though it is still there. I back up my interface twice daily (logon and loggoff) and I make a new folder for each one. I keep anywhere from 5 to 10 days depending on how major any recent changes are.

Basically, I make a folder for each backup that, in turn, has 2 folders:

Interface - just a copy of the interface folder that is in the Runes of Magic folder in the Programs or Programs86 folder.

Variables - the full contents of the hidden RunesOfMagic folder Peryl referred to.

Its an annoyance but it gets to be easy to fix.

[Rossbot]

Thank you so much!!!

Is there a way to change those batch files to do multiple characters?

[Peryl]

Sorry for the delay.

The batch files shown above are more for example than anything else, I wrote them up directly in that post.

Try these instead. Haven't completely tested these and as I don't even have the game installed, I'm still a little iffy on the actual folder.

Anyhoo, you'll need to set the correct folder in both batch files (the line that starts with pushd). Make sure that it goes into the hidden Runes of Magic folder in your documents folder. I've also commented them so you know what each part is doing.

They can be run from anywhere on your computer since it goes to the correct folder(s) it needs to, and returns to the folder it started from.

(Oh yeah, since I run Linux instead of Windows, the line endings may be a little messed up if you just cut and paste from this post so make sure the lines are right).


BackupSettings.bat

@echo off
rem ==========================================
rem ==      Backup UI/add-on settings       ==
rem ==========================================


rem **** Change to RoM's settings folder, saving current folder location ****
pushd "c:\Documents and Settings\whatever\My Documents\Runes of Magic"


rem **** Create the backup folders if they don't exist ****
if not exist ..\RoMBackup md ..\RoMBackup
for /d %%n in (*) do if not exist ..\RoMBackup\%%n md ..\RoMBackup\%%n


rem **** Backup the main SaveVariables.lua file ****
copy /y SaveVariables.lua ..\RoMBackup


rem **** Backup character specific SaveVariables.lua files ****
for /d %%n in (*) do if exist .\%%n\SaveVariables.lua copy /y .\%%n\SaveVariables.lua ..\RoMBackup\%%n


rem **** Go back to folder we originally came from ****
popd
echo Settings Backup Completed.
pause

RestoreSettings.bat

@echo off
rem ==========================================
rem ==      Restore UI/add-on settings      ==
rem ==========================================


rem **** Change to RoM's settings folder, saving current folder location ****
pushd "c:\Documents and Settings\whatever\My Documents\Runes of Magic"


rem **** Ensure backup folder exists ****
if not exist ..\RoMBackup goto abort


rem **** Restore main settings ****
copy /y ..\RoMBackup\SaveVariables.lua .


rem **** Restore all saved character specific settings ****
cd ..\RoMBackup
for /d %%n in (*) do if exist "..\Runes of Magic\%%n" copy /y .\%%n\SaveVariables.lua "..\Runes of Magic\%%n"


goto done


:abort
rem **** Exit with error message ****
popd
echo No backup folder to restore from, aborting.
pause
exit


:done
rem **** Go back to folder we originally came from ****
popd
echo Settings Restored from Backup.
pause

[Rossbot]

Thank you very much Peryl, I do know a little bit about programming, probably enough to understand some of that. I run Windows 7 so I'm not sure what you mean by "line endings" being different. I will test them out tonight and tell you if I have any issues.

How do I specify which characters I want save/restored? Nevermind, I guess it saves/restores all characters. Perfect.

[heoboy123]

Hello, I have a problem with the batch file. When executed, it said

SaveVariables.lua
The system cannot find the file specified.
0 file<s> copied.

Please help

[Peryl]

Hello, I have a problem with the batch file. When executed, it said

SaveVariables.lua
The system cannot find the file specified.
0 file<s> copied.

Please help

1) Make sure the path is correct. The line starting with pushd should go to your settings folder. You will, at minimum, need to change the whatever in this line to match your Windows login name.

2) Make sure that there is an actual SaveVariables.lua file to copy (I'm pretty sure that is what it is called, but I could be remembering wrong).

3) Make sure the character folders are indeed off the main settings folder (I'm fairly sure they are, but again this is from memory so I could be forgetting a sub-folder somewhere)

4) Check that it isn't trying to also use another folder in there that isn't a character. The batch file is pretty stupid and if there is such a folder, the batch file will think it is a character and copy its SaveVariables.lua file which of course doesn't exist. If this is the case, you can safely ignore the message.

And finally,
5) Check if the batch file didn't do the job anyway.

[heoboy123]

Thank you for your reply

My hidden RoM folder path: C:\Users\ADMIN\Documents\Runes of Magic

So in the batch file: pushd "C:\Users\ADMIN\Documents\Runes of Magic"

Do I have to change anything else beside that? I do have SaveVariables.lua. It does create the folder but nothing in there

When I run the batch file it shows only the above 3 lines plus Settings Backup Completed. Press any key to continue